AS62467

Internet exchanges (3 total)

• FD-IX - Houston
• DE-CIX Houston
• DE-CIX Dallas

Facilities (26 total)

• Equinix DA1 - Dallas
• Equinix DA3 - Dallas
• Netrality Houston - 1301 Fannin
• Digital Realty DFW (2323 Bryan St)
• Equinix DA - Dallas (previously Infomart Dallas)
• CyrusOne Dallas (Carrollton)
• Databank Houston West (HOU1) (HOU2)
• Databank Houston Galleria (HOU5)
• EdgeConneX Houston (EDCHOU01)
• Flexential - Dallas/Downtown (DAL01)
• Equinix DA6 - Dallas
• Data Foundry Houston 2
• Cologix DAL2
• Cologix DAL1
• DataBank Dallas (DFW5)
• Equinix DA2 - Dallas
• Evocative DA4
• QTS Irving - Dallas (DFW1)
• DataBank Dallas (DFW1)
• TRG Datacenters Houston (HOU1) (HOU2)
• Aligned Dallas (DFW-01)
• QTS Fort Worth (FTW1)
• FIBERTOWN Bryan Data Center
• FIBERTOWN Houston Data Center
• Cologix DAL3

This ASN's full card — routing footprint, peers, conflicts and RIR facts.

MATCH (a:ASN {name: $asn})
OPTIONAL MATCH (a)-[:HAS_NAME]->(an:ASN_NAME)
OPTIONAL MATCH (a)-[:HAS_COUNTRY]->(co:COUNTRY)
OPTIONAL MATCH (a)-[:REGISTERED_BY]->(org:ORGANIZATION)
WITH a,
     collect(an.name) AS operatorNames,
     collect(co.name) AS countries,
     collect(org.name) AS organizations
OPTIONAL MATCH (a)-[:ROUTES]->(prefix:ANNOUNCED_PREFIX)
WITH a, operatorNames, countries, organizations,
     collect(prefix.name)[0..25] AS samplePrefixes
OPTIONAL MATCH (a)-[:BGP_NEIGHBOR]-(peer:ASN)
OPTIONAL MATCH (peer)-[:HAS_NAME]->(peern:ASN_NAME)
WITH a, operatorNames, countries, organizations, samplePrefixes,
     collect({asn: peer.name, operator: peern.name})[0..25] AS samplePeers
OPTIONAL MATCH (a)<-[:CONFLICTS_WITH]-(conflict:ANNOUNCED_PREFIX)
WITH a, operatorNames, countries, organizations, samplePrefixes, samplePeers,
     collect(conflict.name)[0..25] AS sampleConflicts
OPTIONAL MATCH (a)-[:HAS_SIGNAL]->(sig:THREAT_SIGNAL_TYPE)
WITH a, operatorNames, countries, organizations, samplePrefixes, samplePeers, sampleConflicts,
     collect(DISTINCT sig.name) AS signals
OPTIONAL MATCH (a)-[:IX_MEMBER]->(ix:INTERNET_EXCHANGE)
WITH a, operatorNames, countries, organizations, samplePrefixes, samplePeers, sampleConflicts, signals,
     collect({id: ix.id, name: ix.name})[0..25] AS sampleExchanges
OPTIONAL MATCH (a)-[:AS_PRESENT_AT]->(fac:FACILITY)
WITH a, operatorNames, countries, organizations, samplePrefixes, samplePeers, sampleConflicts, signals, sampleExchanges,
     collect({id: fac.id, name: fac.name})[0..25] AS sampleFacilities
OPTIONAL MATCH (roa:ROA)-[:ROA_AUTHORIZES_ORIGIN]->(a)
WITH a, operatorNames, countries, organizations, samplePrefixes, samplePeers, sampleConflicts, signals, sampleExchanges, sampleFacilities,
     collect({prefix: roa.prefix, maxLength: roa.maxLength})[0..10] AS sampleRoas
CALL { WITH a MATCH (a)-[:ROUTES]->(p:ANNOUNCED_PREFIX) RETURN count(p) AS prefixCount }
CALL { WITH a MATCH (a)-[:BGP_NEIGHBOR]-(n:ASN) RETURN count(n) AS peerCount }
CALL { WITH a MATCH (a)<-[:CONFLICTS_WITH]-(c:ANNOUNCED_PREFIX) RETURN count(c) AS conflictCount }
CALL { WITH a MATCH (a)-[:ROA_AUTHORIZES_ORIGIN]-(r:ROA) RETURN count(r) AS roaCount }
CALL { WITH a MATCH (a)-[:AS_PRESENT_AT]->(f:FACILITY) RETURN count(f) AS facilityCount }
CALL { WITH a MATCH (a)-[:IX_MEMBER]->(x:INTERNET_EXCHANGE) RETURN count(x) AS ixpCount }
RETURN a.name AS name,
       a.rir AS rir,
       a.orgName AS orgName,
       a.asRank AS asRank,
       a.coneAsns AS coneAsns,
       a.conePrefixes AS conePrefixes,
       a.coneAddresses AS coneAddresses,
       a.registrationDate AS registrationDate,
       a.reputationScore AS reputationScore,
       a.reputationCategory AS reputationCategory,
       a.overallThreatLevel AS overallThreatLevel,
       a.abuseEmail AS abuseEmail,
       a.hijackPostureScore AS hijackPostureScore,
       a.hijackOriginMismatchCount AS hijackOriginMismatchCount,
       a.routeLeakCount AS routeLeakCount,
       a.routeLeakTypes AS routeLeakTypes,
       a.degreeCustomer AS degreeCustomer,
       a.degreePeer AS degreePeer,
       a.degreeProvider AS degreeProvider,
       operatorNames, countries, organizations,
       samplePrefixes, samplePeers, sampleConflicts,
       signals, sampleExchanges, sampleFacilities, sampleRoas,
       prefixCount, peerCount, conflictCount, roaCount, facilityCount, ixpCount

The five networks that most often share this ASN's observed BGP paths.

MATCH (a:ASN {name: $asn})<-[:BGP_PATH]-(b:BGP_PATH_OBSERVATION)
WITH b LIMIT 200
MATCH (b)-[:BGP_PATH]->(up:ASN)
WHERE up.name <> $asn
WITH up.name AS asn, count(*) AS observations
ORDER BY observations DESC
LIMIT 5
RETURN asn, observations